Frogatto je odlicna platformska igrica, sto bi rekli, komercijalni kvalitet, doduse autori i planiraju da prodaju igru spakovanu za iphone, zato i jeste samo source pod GPL-3 licencom dok su data fajlovi slobodni za nekomercijalnu upotrebu, no to ne bi trebalo da vas spreci da uzivate u igranju ;) Kako nigde jos uvek nema ebuild-a sklepao sam ja jedan.

p.s. fullscreen je ctrl+f

frogatto-1.0.ebuild

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
 
EAPI=2
inherit eutils games
 
DESCRIPTION="Frogatto is a platformer or jump-and-run videogame"
HOMEPAGE="http://www.frogatto.com"
SRC_URI="http://www.frogatto.com/files/${P}.tar.bz2"
 
LICENSE="GPL-3 free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
 
RDEPEND="dev-libs/boost
    media-libs/libsdl[opengl]
    media-libs/sdl-mixer[vorbis]
    media-libs/sdl-image[png]
    media-libs/sdl-ttf
    media-libs/glew
    media-libs/libpng"
DEPEND="${RDEPEND}"
 
src_prepare() {
    sed -i -e "s/ccache //g" Makefile || die "sed failed"
}
 
src_compile() {
    emake OPT="${CFLAGS}" || die "emake failed"
}
 
src_install() {
    newgamesbin game ${PN}.bin || die "newgamesbin failed"
    games_make_wrapper ${PN} ${PN}.bin "${GAMES_DATADIR}"/${PN}
    insinto "${GAMES_DATADIR}"/${PN}
    doins -r data images music music_aac sounds sounds_wav *.ttf || die "doins failed"
    newicon images/window-icon.png ${PN}.png
    make_desktop_entry ${PN} Frogatto
    prepgamesdirs
}